Server : Apache System : Linux host44.registrar-servers.com 4.18.0-553.44.1.lve.el8.x86_64 #1 SMP Thu Mar 13 14:29:12 UTC 2025 x86_64 User : vapecompany ( 2719) PHP Version : 7.4.33 Disable Function : NONE Directory :  /proc/self/root/proc/self/root/usr/share/groff/1.22.3/font/devps/generate/

Upload File : current_dir [ Writeable ] document_root [ Writeable ]

#! /usr/bin/sed -f
# Set up uniform vertical dimensions for extensible glyphs (needed by eqn).
/^C .*[ ;]N bracketlefttp[ ;]/bx
/^C .*[ ;]N bracketleftex[ ;]/bx
/^C .*[ ;]N bracketleftbt[ ;]/bx
/^C .*[ ;]N bracketrighttp[ ;]/bx
/^C .*[ ;]N bracketrightex[ ;]/bx
/^C .*[ ;]N bracketrightbt[ ;]/bx
/^C .*[ ;]N bracelefttp[ ;]/bx
/^C .*[ ;]N braceleftmid[ ;]/bx
/^C .*[ ;]N braceleftbt[ ;]/bx
/^C .*[ ;]N bracerighttp[ ;]/bx
/^C .*[ ;]N bracerightmid[ ;]/bx
/^C .*[ ;]N bracerightbt[ ;]/bx
/^C .*[ ;]N braceex[ ;]/bx
/^C .*[ ;]N parenleftex[ ;]/by
/^C .*[ ;]N parenrightex[ ;]/by
/^C .*[ ;]N parenleftbt[ ;]/bz
/^C .*[ ;]N parenrightbt[ ;]/bz
/^EndCharMetrics/a\
italicCorrection integral 67\
leftItalicCorrection integral 52\
subscriptCorrection integral -10
b
:x
s/B \([-0-9][0-9]*\) [-0-9][0-9]* \([-0-9][0-9]*\) [-0-9][0-9]*/B \1 -75 \2 925/
b
:y
s/B \([-0-9][0-9]*\) [-0-9][0-9]* \([-0-9][0-9]*\) [-0-9][0-9]*/B \1 -80 \2 920/
b
:z
s/B \([-0-9][0-9]*\) \([-0-9][0-9]*\) \([-0-9][0-9]*\) [-0-9][0-9]*/B \1 \2 \3 920/
b